<meta http-equiv="Pragma" content="no-cache">
<!-- Pragma content set to no-cache tells the browser not to cache the page -->

'================================================================
'
'''Form1 general declaration
Option Explicit
Dim close_ie_flag As Boolean
Private Declare Sub Sleep Lib "kernel32" (ByVal dwMilliseconds As Long)
'
'================================================================

Private Sub Command1_Click()
   
Dim IE As InternetExplorer
Set IE = New InternetExplorer ''''Create new instance of the object
'''The InternetExplorer object lets you control a remote instance of IE.
'''To use it, add a reference to "Microsoft Internet Controls" from the VB6 IDE.
'''To do that, go to menu Project\References and select it from the list.

Dim ie_current_url As String
Dim ie_last_known_url As String
Dim refresh_counter As Long
Dim refresh_allowed As Boolean


On Error GoTo UnexpectedError

close_ie_flag = False
Command2.Enabled = True
Command1.Enabled = False
refresh_counter = 0

IE.Visible = True
IE.Navigate "http://www.mcselec.com/index2.php?option=com_forum&Itemid=59"

ie_last_known_url = IE.LocationURL '''Get the current URL

Do

    ie_current_url = IE.LocationURL  '''Get the current URL

   
    If ie_current_url <> ie_last_known_url Then  '''The URL has changed?
       
        refresh_allowed = True
               
               
        If InStr(1, ie_current_url, "posting", 1) Then '''no refresh while posting
           
            refresh_allowed = False
            Me.Caption = "P Autorefresh " '''P like POSTING        
        End If
       
       
        If InStr(1, ie_current_url, "page=privmsg", 1) Then '''no refresh while using PM
           
            refresh_allowed = False
            Me.Caption = "PM Autorefresh " '''PM like PRIVATE MESSAGE        
        End If
 
             
        If InStr(1, ie_current_url, "page=search", 1) Then '''no refresh while searching
           
            refresh_allowed = False
            Me.Caption = "S Autorefresh " '''S like SEARCH
        End If


        If refresh_allowed = True Then
       
            IE.Refresh '''refresh our IE browser window
            ie_last_known_url = ie_current_url
            refresh_counter = refresh_counter + 1
            Me.Caption = refresh_counter & " Autorefresh "
            '''The form caption will show a counter with the number of refresh performed.
            '''If you have the Windows Taskbar always visible, you will see the counter
            '''even when this program is minimized or is behind the IE browser window.
       
        End If
       
       
       
    End If
   
   
    Sleep 100  '''100 ms, Windows API call

    DoEvents

Loop Until close_ie_flag = True '''See Command2_Click()

IE.Quit  '''Close the browser
Set IE = Nothing  '''Clean up

Command1.Enabled = True
Command2.Enabled = False

Me.Caption = "Autorefresh"

Exit Sub

UnexpectedError:
'''You get an error if you close the IE browser instance from its GUI
'''The program can take up to 3 seconds to recover from this error.
Set IE = Nothing  '''Clean up
Command2.Enabled = False
Command1.Enabled = True
Me.Caption = "Autorefresh"

End Sub

'================================================================

Private Sub Command2_Click()
    close_ie_flag = True '''Terminate the loop in Command1_Click()
End Sub

'================================================================

Private Sub Form_Load()
    Me.Caption = "Autorefresh"
    Command1.Enabled = True
    Command1.Caption = "Open forum www.mcselec.com"
    Command2.Caption = "Close forum www.mcselec.com"
    Command2.Enabled = False
End Sub

'================================================================