$regfile = "m8def.dat"

'CONNECT SIGNAL INTO THE PORTD.4 (T0 INPUT)

$Crystal=8000000
$hwstack=64
$swstack=32
$framesize=128


Config Timer0 = Counter , Edge = Rising                'no prescale
Enable Timer0                                          'enable counting 256 overflow
On Timer0 Timer0_isr                                   'when Time rich 256 jump Interrupt will be fired
Enable Timer0                                          'allow this interrupt

'now we need 1second timer
Config Timer1 = Timer , Prescale = 256 , Compare_a = Disconnect , Compare_b = Disconnect , Clear_timer = 1
 Compare1a = 31249                                     '1000ms @8MHz/256  =1s
Enable Compare1a : On Compare1a Timer1_isr

Dim Overflows As Byte , Copy_overflows As Byte , Copy_of_timer As Byte
Dim Its_time As Byte , Helpd As Dword

Enable Interrupts

Do
 If Its_time = 1 Then
  Helpd = Copy_overflows
   Shift Helpd , Left , 8                              'multiply overflows by 256x times quicly
  Helpd = Helpd + Copy_of_timer                        'add rest of pulses
  Print "Freq=" ; Helpd ; "Hz"
 Its_time = 0
 End If

Loop


Timer0_isr:                                            'timer count 256/overflow
 Incr Overflows                                        'count 256`s
Return


Timer1_isr:                                            'every second
Copy_of_timer = Timer0
 Copy_overflows = Overflows
  Overflows = 0
    Its_time = 1
Return