$REGFILE = "m128def.dat"                                    '<- whatever your chip is
$CRYSTAL = 16000000                                         '<- your crystal
$BAUD = 9600                                                '<- USART0 baud rate

DIM USART0_Buffer(6) As Byte                                  '<- 6 character buffer
DIM USART0_Pointer As Byte

DIM TEMP As Byte

DIM USART0_Status As Byte

DataReady ALIAS USART0_Status.1
StartCondition ALIAS USART0_Status.0

USART0_Pointer = 1                                          '<- initialize the pointer to the start of the buffer

StartByte ALIAS USART0_Buffer(1)
DataByte1 ALIAS USART0_Buffer(2)
DataByte2 ALIAS USART0_Buffer(3)
DataByte3 ALIAS USART0_Buffer(4)
DataByte4 ALIAS USART0_Buffer(5)
ChkSumByte ALIAS USART0_Buffer(6)

CONST TRUE = 1
CONST FALSE = 0
CONST PASSED = 0

CONST StartByteValue = &H03                                 '<- make this whatever your start byte is supposed to be

DIM ChecksumCode As Byte

CONFIG Com1 = Dummy , Synchrone = 1 , Parity = None , Stopbits = 1 , Databits = 8 , Clockpol = 0


ENABLE URXC : ON URXC USART0_RXC_ISR                        'allow interrupts on USART0 receive complete

ENABLE INTERRUPTS                                           'globally allow interrupts to occur



'MAIN

DO

WHILE DataReady = TRUE

   'do something with DataByte1
   'do something with DataByte2
   'do something with DataByte3
   'do something with DataByte4

   'you are done so reset the DataReady flag
   DataReady = FALSE

WEND

LOOP

END

USART0_RXC_ISR:

TEMP = UDR                                                  '<- put the contents received from the UART data register into TEMP

IF TEMP = StartByteValue THEN                               '<- see if it matches your start byte value

   StartCondition = TRUE

END IF

IF StartCondition = TRUE THEN

   SELECT CASE USART0_Pointer

         CASE 1                                             'the start byte

            USART0_Buffer(USART0_Pointer) = TEMP
            INCR USART0_Pointer                             '<- increment for the next character to come

         CASE 2 TO 5                                        '4 data bytes

            USART0_Buffer(USART0_Pointer) = TEMP
            INCR USART0_Pointer                             '<- increment for the next characters to come

         CASE 6                                             'the checksum byte

            USART0_Buffer(USART0_Pointer) = TEMP

            'here you can perform a test of the buffer and checksum
            'i don't know your checksum code so we'll just pretend it's here
            'and it's result is called ChecksumCode

            'checksum routines should equal zero when perfomed on an array
            'that includes a checksum received

            IF ChecksumCode = PASSED THEN                   'the result of the checksum routine is zero

               DataReady = TRUE                             'let the main program know it can do whatever it wants with this data
               StartCondition = FALSE                       'reset for the next data packet to arrive
               USART0_Pointer = 1                           'reset the buffer pointer for the next data packet

            ELSE                                            'checksum test routine says the data failed

               StartCondition = FALSE                       'reset for the next data packet
               USART0_Pointer = 1                           'reset the buffer pointer for the next data packet

            END IF

   END SELECT

END IF

RETURN